I've been tweaking/adding to the script for myself for quite some time, but never really got around to finalizing a new version I was comfortable putting out there. Mostly as it involved creating/redo'ing the menus as many of my tweaks were hardcoded into the script, and menus aren't fun. I ended up pretty much rewriting the entire script in the process, as I figured out some better/cleaner ways to do things. But before I add the new functions (which I'll go into detail about below), I want to test the core of the script. This should be faster/smoother than the old version... Buuut you never know. Hence the beta testing ;P
This beta version includes all the old stuff from the last version I released (7.10 wayyy back in 2016): rearms abilities, MS, auto-casts chiv spells, tithe warning, etc. For the uninitiated, please check out the old rearmer thread for details/instructions. It also includes completely redesigned menus, customizable default settings, a new hotkey system, and a soft-reset function. Once I'm sure I didn't break it completely, I'll add the other fun new things, like the WW auto-detect/switch function.
So yeah, take it for a test spin. Let me know if you run into any issues, if anything isn't clear, or there's any changes you'd like to see. Once I'm pretty sure that this is stable, I'll add in the few things that aren't included. A brief summary of the new changes:
New Functions:
- Soft Reset: A hotkey/button that should fix the bug where an ability will flash on/off, or doesn't activate at all. This usually happens when you switch weapons too quickly; toggling a weapon on/off would fix it, but now there's a button for it.
- Whirlwind Auto-Detect: Identical to the MS auto-switch feature, except it works for whirlwind weapons. If there's 2+ enemies in range, you use WW; otherwise, you switch to the other ability. This feature is not implemented yet!
- Divine Fury: The current setup casts DF when you dip below 75% stam, so you're always attacking at 100% speed. Added another option to cast DF on a timer (as well as stamina based) so the SSI, HCI, and damage increase (which works outside the DI cap) boosts are always active. Also not implemented yet.
- Modifier Hotkeys: Added a fancy new hotkey binding system that allows you to use Control/Alt/Shift + whatever hotkey you want.
- Customizable Defaults: Made a bunch of changes that let's you adjust the default settings for a bunch of stuff. The previous version let you change the default ability on startup... and that's it. Now, you can adjust the default ability, what MS switches to, where the menu window opens, if counter attack is active upon starting the script, and something else I can't remember.
New Menu System:
- Main Menu: Similar to the old version. Added the reset button and WW auto-detect. Moved the default ability dropdown (and all other startup settings) to the second menu.
- 2nd Menu (Settings): A new submenu where you can change default settings, redo the initial setup, and change hotkey bindings.
- 3rd/4th Menus (Hotkeys): Again, similar to the old version, but includes new bindable functions, the option to include a key modifier (ctrl/alt/shift), and just looks prettier.
- Help Buttons: All the submenus have a "?" button that gives you a description of what all the settings affect.
NOTE: Redo the initial setup. Some of the stuff used to save your settings has changed slightly.
Code: Select all
; Script: Rearmer
; Author: Devlin
; Current Version: 8.05
; Purpose: Yeet
; Todo:
; Implement new stuff after testing
; Disable autocasting in TC/around banks
; CW autocast on timer or based on enemies
; Weight Check
; Editfield for minimum mana/stam and CW cast timer
; Highlight current menu options
; Relayered weapon damage check thingy.
gosub Startup
if *StartupSub <> Off
{
gosub StartupOn
}
gosub menu
gosub Settings
;menu hide ; Hides menu on startup
loop:
wait 10
repeat
{
if #charGhost = NO && #MAXMANA > %mana
{
if ( Abs ( %min - #minDmg ) > 15 ) || ( ( %max <> #maxDmg ) > 15 )
{
wait 15 ; Make this higher if abilities don't rearm on wep change.
gosub Settings
set %min #minDmg
set %max #maxDmg
goto loop:
}
}
else
{
goto loop:
}
;---------------------------------------
; Functions
;---------------------------------------
gosub Buttons
gosub Hotkeys
gosub %Sub ; Abilities (Prim/Sec/MS)
gosub %Sub2 ; Counter Attack
gosub %Sub3 ; Consecrate Weapon
gosub %Sub4 ; Divine Fury
gosub %Sub10 ; Tithe Warning
;gosub %Sub5 ; WW Status ; XXX
;gosub %Sub11 ; Check Item ; xxx
;---------------------------------------
; End Functions
;---------------------------------------
}
until ( #mana <= %mana )
{
event sysmessage You are out of Mana!
wait 2s
}
goto loop:
;-----------------------------------------
; Ability Subs
;-----------------------------------------
sub Prim
cmppix 1 t
event macro 35 0
return
sub Sec
cmppix 2 t
event macro 36 0
return
sub MS
if ( ( #scnt - %T_MS ) < 1 )
{
if %MSSwitch = MS
event sysmessage MS will not switch.
else
event sysmessage MS will switch to %MSSwitch when there are 2+ targets.
wait 1s ; on ability change
}
Finditem %Monsters %MSRange ; Check for mobs in melee or bow range
if #Findcnt > 1
{
cmppix 3 t ; If there's 2+ mobs in range
event macro 15 150
wait 5
}
else
{ ; If less than 2
cmppix %MSPix t ; Use "MS Switches to" ability
event macro %MSNum %MSNum2 ; prim/sec/MS event macro
return
}
return
sub CAOn
if #mindmg > 10 && #targcurs = 0 && #contsize <> 452_236 && #contsize <> 250_115 && ( H notin #charstatus ) && #charGhost = NO && #mana > 5
{
;wait 2
cmppix 4 f
{
event macro 15 148
wait 10
}
}
return
;-----------------------------------------
; Gambit Subs
;-----------------------------------------
sub ConWepOn
Finditem %Monsters G_8
if #Findcnt > 0
{
if #mindmg > 10 && #contsize <> 452_236 && #contsize <> 250_115 && #targcurs = 0 && ( #stamina * 100 ) / #maxstam >= %stam && #mana > 10 && ( H notin #charstatus )
{
if ( #scnt > ( %T_CW + %T_Play ) )
{
wait 1
set %T_Play #scnt
event macro 15 203
wait 1
}
}
}
return
sub DivFuryOn
if ( #stamina * 100 ) / #maxstam <= %stam && #targcurs = 0 && #mana > 10 && #charghost = no && h notin #charstatus
{
;wait 10
event macro 15 205
wait 2
}
return
sub TitheOn
if ( #TP = 0 )
{
return
}
if ( #TP < 10000 )
{
set #sysMsgCol 138
str len #tp
set %len #strres - 1
str left #tp 1 %len
set %tp #strres
str mid #tp %len 5
event sysmessage You are low on Tithing Points ( #TP / 100,000)
set #sysMsgCol 1389
set %Sub10 Off
}
set %TitheTimer #scnt
set %Sub10 Off
return
sub Off
if ( %TitheTimer + 300 < #scnt )
{
set %Sub10 TitheOn
}
;set %T_Hold2 #scnt
return
;-----------------------------------------
; Binding Stuff
;-----------------------------------------
sub HotButtKey
wait 1
set #menubutton 0
set % . %1 %2
if %1 = Sub
{
menu Font Color black
menu Font BGColor $F9F9F9
event sysmessage %3 Ability activated
event exmsg #charid 3 0 [ , %3 , ]
set %T_MS #scnt
}
if %1 = Sub2
event sysmessage Counter Attack is %3 , .
if %1 = Pause
{
;set %T_Hold #scnt
set %Sub2 %2
set %Sub3 %2
event sysmessage Casting is Paused. Press Play or *PlayMod *Play to Resume.
}
if %1 = Play
{
Set %Sub2 %2
set %Sub3 %3
event sysmessage Casting Resumed. Press Pause or *PauseMod *Pause to Pause.
}
if %1 = Reset
{
gosub Settings
wait 5
event exmsg #charid 3 0 [Reset]
event sysmessage Ability Reset
}
gosub ParamFlush %0
wait 1
return
sub MSButtKey
wait 1
set #menubutton 0
if %1 <> Range
{
set %MSSwitch %1
set %MSPix %2
set %MSNum %3
set %MSNum2 %4
if %1 = MS
event sysmessage MS will not switch.
else
event sysmessage MS switches to %1 ability when only 1 target is in range.
;Momentum Strike will be activated when there are two or more targets. Current mode if less than two targets: %MSPix
}
else
{
set %MSRange %2
event sysmessage MS active for %3 (when 2+ targets are within %4 tiles).
}
gosub ParamFlush %0
wait 1
return
sub Hotkeys
onhotkey *Prim *PrimMod
gosub HotButtKey Sub Prim Primary 1 Primary
onhotkey *Sec *SecMod
gosub HotButtKey Sub Sec Secondary 2 Secondary
onhotkey *MS *MSMod
gosub HotButtKey Sub MS Momentum , #spc , Strike 3 M1MS
onhotkey *Pause *PauseMod
gosub HotButtKey Pause Off
onhotkey *Play *PlayMod
gosub HotButtKey Play CAON ConWepOn
onhotkey *Reset *ResetMod
gosub HotButtKey Reset
onhotkey *Show *ShowMod
menu show
onhotkey *Hide *HideMod
{
menu hide
event sysmessage Menu Hidden. Hit *ShowMod *Show to show the menu again.
}
return
sub ParamFlush
; passes # of parameters (%0) as %1, cycle through/reset.
for %i 1 %1
set % . %i
return
sub Buttons
set #lpc 100
;-----------------------------------------
; Main Menu
;-----------------------------------------
if #menuButton = Primary
gosub HotButtKey Sub Prim Primary 1 Primary
if #menuButton = Secondary
gosub HotButtKey Sub Sec Secondary 2 Secondary
if #menuButton = M1MS
gosub HotButtKey Sub MS Momentum , #spc , Strike 3 M1MS
if #menubutton = CAON
gosub HotButtKey Sub2 CAON On
if #menubutton = CAOFF
gosub HotButtKey Sub2 Off Off
if #menubutton = MSMelee
gosub MSButtKey Range G_1 Melee 1
if #menubutton = MSBow
gosub MSButtKey Range G_8 Bows 8
if #menubutton = MSPrim
gosub MSButtKey Primary 1 35 0
if #menubutton = MSSec
gosub MSButtKey Secondary 2 36 0
if #menubutton = MSOnly
gosub MSButtKey MS 3 15 150
if #menubutton = WWOn
;
if #menubutton = WWOff
;
if #menubutton = M1Pause
gosub HotButtKey Pause Off
if #menubutton = M1Play
gosub HotButtKey Play CAON ConWepOn
if #menubutton = M1Reset
gosub HotButtKey Reset
if #menubutton = M1Settings
{
menu clear
gosub menu2
}
if #menuButton = Closed
stop
;-----------------------------------------
; Menu2 (Settings)
;-----------------------------------------
if #menubutton = Hotkeys
{
menu clear
gosub menu3
}
if #menubutton = RedoSetup
{
gosub Setup
set #menubutton 0
}
if #menubutton = MenuPos
gosub menuPos
if #menubutton = M2?
{
display ok Default Ability: Active ability on startup.
+ $$MS Switches To: Default MS switch-to ability.
+ $$WW Auto-Detect: Enables/disables the Whirlwind Auto-Detect function.
+ $$$Hotkey Bindings: Edit your key bindings.
+ $$Redo Setup: Redo the "hover your mouse over the icon" setup thingy.
+ $$Save Menu Position: Saves the location of the menu so it will reopen there always.
;Divine Fury: NOT IMPLEMENTED YET. Will eventually allow you to cast Divine Fury on a timer, or only to replenish stamina.
;Counter Attack: NOT IMPLEMENTED YET. Changes if Counter Attack is paused or not upon starting the script.
set #menubutton 0
}
if #menubutton = M2Save
{
menu get drop
if #menures <> *drop
set *drop #menures
menu get MSdrop
if #menures <> *MSdrop
set *MSdrop #menures
menu get WWdrop
if #menures <> *WWdrop
set *WWdrop #menures
;menu get DFdrop
;if #menures <> *DFdrop
; set *DFdrop #menures
set #menures
menu clear
gosub menu
}
;-----------------------------------------
; Menu3 (Hotkey Front Menu)
;-----------------------------------------
if #menubutton = Prim || #menubutton = Sec || #menubutton = MS ||
+ #menubutton = Pause || #menubutton = Play || #menubutton = Reset ||
+ #menubutton = Show || #menubutton = Hide
{
set %HKType #menubutton
menu clear
gosub menu4 %HKType
gosub Bindings %HKType
}
if #menubutton = M3Save
{
;display OkCancel Save current hotkey assignments?
;if #dispres = Ok
;{
menu clear
gosub menu2
event sysmessage Hotkeys saved.
; set #dispres 0
;}
}
if #menubutton = M3?
{
display Ok Soft Reset should fix the ability flashing on/off bug, or not activating at all
+ (you may need to hit it a couple times to work).
+ $$Pause/Play Casting only affects consecrate weapon/counter attack. Abilities/Divine Fury are always active.
+ $$Hide/Show Menu toggles the primary menu display on/off.
+ $$Keymap shows your current bindings.
set #menubutton 0
}
if #menubutton = Keymap
{
menu clear
gosub menu5
}
if #menubutton = M5Save
{
menu clear
gosub menu3
}
set #lpc 10
return
sub MenuPos
gosub menu
menu clear
menu button BEGIN 65 45 50 25 BEGIN
menu button Cancel 135 90 50 25 Cancel
display ok Move the menu window to the location you want it. After you press the BEGIN button
+ a red circle will appear. Place your cursor in the middle of it. You'll have 3 seconds to do so.
+ $$Press Cancel if you do not wish to save the window location.
mploop:
if #menubutton = BEGIN
goto exit:
if #menubutton = Cancel
{
menu clear
gosub menu2
return
}
goto mploop:
exit:
menu delete BEGIN
menu delete Cancel
menu text abc 1 1 Move cursor into red circle!
menu Shape ShapeC 92 52 5 5 1 6 1 red 7 red
wait 3s
set *rearmerMenuX #cursorX - 90
set *rearmerMenuY #cursorY - 50
menu clear
gosub menu2
return
sub Bindings
;-----------------------------------------
; Menu4 (Hotkey Selector)
;-----------------------------------------
set %mb #menubutton
bLoop:
repeat
{
;
}
until #menubutton <> %mb
if #menubutton <> M4Save && #menubutton <> M4? && #menubutton <> Clear
{
if #menubutton = Ctrl || #menubutton = Alt || #menubutton = Shift
{
set %temp %1 , Mod
set * . %temp #menubutton
menu delete CBMod
menu text CBMod 145 30 #menubutton
}
else if #menubutton <> 0
{
set * . %1 #menubutton
menu delete CB
menu text CB 205 30 #menubutton
}
}
else
{
if #menubutton = Clear
{
set %temp %1 , Mod
set * . %temp
menu delete CBMod
menu text CBMod 145 60
set * . %1
menu delete CB
menu text CB 205 60
}
if #menubutton = M4Save
{
set %temp %1
set %temp2 %1 , Mod
display OkCancel Save %1 hotkey assignment?
+ $Hotkey: * . %1
+ $Modifier: * . %temp2
if #dispres = Ok
{
event sysmessage %1 hotkey saved.
menu clear
gosub menu3
set #dispres 0
goto bExit:
}
}
if #menubutton = M4?
{
display ok The current %1 binding is shown above.
+ You may select F1-F12, Home/End/Insert/Delete.
+ A single modifier (Ctrl/Alt/Shift) may also be included.
}
}
set #menubutton %mb
goto bLoop:
bExit:
set #menubutton 0
gosub ParamFlush %0
return
;-----------------------------------------
; Startup Subs
;-----------------------------------------
; 53 yellow
; 906 my gray font
; 1385 nice green
; 1387 nice white
; 1389 old white, too bright use 1489
; 1391 nice light blue
; 1464 light red
; 1485 red warning
sub Startup
event macro 8 2
set #sysMsgCol 1489
set %min #minDmg
set %max #maxDmg
set %mana 25 ; XXX Make editable in menu?
set %T_CW 10
;set %pause 50 ; UNUSED. Divine Fury spam prevention
set %stam 75 ; % Stamina Divine Fury is cast at.
set %Sub3 ConWepOff
set %Sub4 DivFuryOn
set %Sub10 TitheOn
set %MSRange G_1 ; XXX add default/save option to menu 2
set %Monsters CN_LC_UC_WE_ZC_YD_CF_YE_ED_OD_QE_BH_DH_LH_AF_TE_OJ_OO_TO_QH_SE_PE_Q_HI_T_TI_DJ_VE_GO_II_NI_CC_KI_UE_AHB_CH_VI_PH_IJB_JE_AP_HE_CI_OE_BI_IE_HF_EJ_JGB_LO_AI_VC_ND_AB_Z_DI_FH_Y_WI_BE_BHB_FE_DE_AE_R_EB_WD_HH_KH_P_GF_GH_CBB_BBB_EBB_W_NE_BJ_HH_NC_UB_RB_TD_UD_YAB_RO_SD_PI_WGD_MD_RE_KD_SB_IB_QO_YH_DD_JJ_UAB_QD_XAB_I_XH_YB_PD_HD_XE_CD_DF_TGB_FO_IH_FD_V_GD_KHB_VGB_QGB_RI_QHB_DBB_ME_EH_TH_CBH_KE_BD_SI_S_KJ_DW_VH_UF_BG_CO_ZI_XG_YG_BB_RF_AG_NG_IG_MH_CG_LD_JI_JG_KG_OH_JB_XF_JD_CB_RD_AH_XD_WF_TG_OF_SG_MG_MB_EG_KB_YF_TF_VF_NF_WG_WJ_WB_PF_M_DG_GE_ZD_NN_WM_ZM_BN_AC_UGB_OC_MC_PJ_ZJ_CK_AK_J_EC_K_PB_NB_SC_SH_EF_WH_FJ_UI_U_QE_QF_GB_GHB_HBB_MO_XI_PO_BF_CHB_WGB_NH_TAB_XO_ZO_NO_TM_SO_YO_WO_GJ_DN_JHB_ZAB_QJ_TCIJ_KF_DO_OI
if *menuX = N/A
set *menuX 750
if *menuY = N/A
set *menuY 750
if *drop = N/A
set *drop 1
if *drop = 1
set %Sub Prim
if *drop = 2
set %Sub Sec
if *drop = 3
set %Sub MS
if *MSdrop = N/A
set *MSdrop 1
if *MSdrop = 1
{
set %MSPix 1 ; cmppix scan for primary
set %MSSwitch Primary
set %MSNum 35
set %MSNum2 0
}
if *MSdrop = 2
{
set %MSPix 2 ; cmppix scan for secondary
set %MSSwitch Secondary
set %MSNum 36
set %MSNum2 0
}
if *MSdrop = 3
{
set %MSPix 3 ; cmppix scan for MS
set %MSSwitch MS
set %MSNum 15
set %MSNum2 150
}
if *WWdrop = N/A
set *WWdrop 1
if *WWdrop = 1
set %Sub5 WWOn
if *WWdrop = 2
set %Sub5 WWOff
loop2:
event macro 15 148
wait 10
if you_must_have_a_weapon in #sysmsg
{
display You must have a weapon equipped to begin.
wait 5s
goto loop2:
}
wait 5
savePix *CountX *CountY 4
event sysmessage Casting is on hold. Hit *PlayMod *Play to begin casting.
return
sub Settings
savePix *PrimX *PrimY 1
savePix *SecX *SecY 2
savePix *MSX *MSY 3
;set *RearmerSave 1
wait 5
return
sub Setup
if *RearmerSave = 1 ; redo setup confirmation
{
display OkCancel Click OK to target your ability icons. Hit Cancel to exit Setup.
if #dispres = Cancel
return
}
display OKCancel Please move your mouse over the Primary Ability Icon. You have 3 seconds to do so. $$Hit Cancel if you do not wish to retarget the Icon.
if #dispres = Ok
{
wait 3s
set *PrimX #CURSORX
set *PrimY #CURSORY
set #dispres 0
}
display OKCancel Please move your mouse over the Secondary Ability Icon. You have 3 seconds to do so. $$Hit Cancel if you do not wish to retarget the Icon.
if #dispres = OK
{
wait 3s
set *SecX #CURSORX
set *SecY #CURSORY
set #dispres
}
display OKCancel Please move your mouse over the Momentum Strike Ability Icon. You have 3 seconds to do so. $$Hit Cancel if you do not wish to retarget the Icon.
if #dispres = OK
{
wait 3s
set *MSX #CURSORX
set *MSY #CURSORY
set #dispres
}
display OKCancel Please move your mouse over the Counter Attack Ability Icon. You have 3 seconds to do so. $$Counter Attack CANNOT be active! Wait until it wears off, then hit OK. ;If you do not use Counter Attack, just hit OK and wait. Hit Cancel if you do not wish to retarget the icon.
if #dispres = OK
{
wait 3s
set *CountX #CURSORX
set *CountY #CURSORY
set #dispres
}
set *RearmerSave 1
display The script is now ready to run.
return
sub StartupOn
if *RearmerSave = 1 ;&& *StartupSub2 = Off
{
display YesNoCancel Do you want to use your previously saved settings?
+ $$Click Cancel to disable this message on startup and always use saved settings. (You can redo the setup at anytime from the menu.)
if #dispres = No
{
gosub Setup
return
}
if #dispres = Cancel
{
set *StartupSub Off
set *RearmerSave 1
}
}
else
{
display OK If this is your first time using Rearmer, please take a moment to read the setup instructions on the forums.
+ $$For the script to work, you MUST:
+ $- Have your status window open.
+ $- Have the Primary, Secondary, MS, and Counter Attack ability icons on your screen.
gosub Setup
}
return
sub menu
menu Window Size 185 115
menu Show *rearmerMenuX *rearmerMenuY
menu Window Title Rearmer
;menu Window transparent 75
menu Font Transparent #false
menu Font Size 7
menu Font Align left
menu Window Color $D1D0CF
menu Font BGColor $D1D0CF ;$E7E7E7
menu Font Style bu
menu Text ActiveAbility 10 2 Ability:
menu Text CA 2 82 CA On/Off:
menu Text MSWep 68 2 MS Weapon:
menu Text MSWepSwitch 60 42 MS Switches To:
menu Text Casting 145 2 Casting:
menu Font Style sb
menu Text WWSwitch 69 82 WW Switch:
menu text www 63 95 TO BE ADDED
menu Font Color black
menu Font BGColor $F9F9F9
menu Font Style
menu Button Primary 0 15 50 20 Primary
menu Button Secondary 0 35 50 20 Secondary
menu Button M1MS 0 55 50 20 MS
menu Button CAON 0 95 25 20 On
menu Button CAOFF 25 95 25 20 Off
menu Button MSMelee 60 15 35 20 Melee
menu Button MSBow 95 15 35 20 Bow
menu Button MSPrim 60 55 24 20 Prim
menu Button MSSec 84 55 23 20 Sec
menu Button MSOnly 107 55 23 20 MS
;menu Button WWOn 70 95 25 20 On
;menu Button WWOff 95 95 25 20 Off
menu Button M1Pause 140 15 45 20 Pause
menu Button M1Play 140 35 45 20 Play
menu Button M1Reset 140 75 45 20 Reset
menu Button M1Settings 140 95 45 20 Settings
return
sub menu2
menu window size 250 150
menu Window Title Settings
menu Font Transparent #true
;menu Window transparent 75
menu Font Transparent #false
menu Font Size 8
menu Font Align
menu Show *rearmerMenuX *rearmerMenuY
menu Window Color $E7E7E7
menu Font BGColor $E7E7E7
menu Font Style b
menu Text M2DA 2 2 Default Ability:
menu Text M2MS 2 42 MS Switches To:
menu Font Style sb
menu Text M2WW 2 85 WW Auto-Detect
menu Text M2DF 2 100 (TO BE ADDED)
menu Text M2DF 2 120 Divine Fury Mode:
menu Text M2DF 2 135 (TO BE ADDED)
;menu Text M2CA 2 162 Counter Attack:
;menu Text M2DF 2 180 (TO BE ADDED)
menu Font Style b
menu Font Color black
menu Font BGColor $F9F9F9
menu Font Style
menu Button Hotkeys 150 0 100 25 Hotkey Bindings
menu Button RedoSetup 150 25 100 25 Redo Setup
menu Button MenuPos 150 50 100 25 Save Menu Position
menu Button M2? 150 125 25 25 ?
menu Button M2Save 175 125 75 25 Save
menu Font Size 7
menu Combo Create drop 1 15 100
menu Combo Add drop Primary
menu Combo Add drop Secondary
menu Combo Add drop MS
menu Combo Select drop *drop
menu Combo Create MSdrop 1 55 100
menu Combo Add MSdrop Primary
menu Combo Add MSdrop Secondary
menu Combo Add MSdrop Stays on MS
menu Combo Select MSdrop *MSdrop
;menu Combo Create WWdrop 1 95 100
;menu Combo Add WWdrop On
;menu Combo Add WWdrop Off
;menu Combo Select WWdrop *WWdrop
;menu Combo Create DFdrop 1 135 100
;menu Combo Add DFdrop Stamina
;menu Combo Add DFdrop Timer
;menu Combo Select DFdrop *DFdrop
return
sub menu3 ; Hotkey Front Menu
menu window size 250 150
menu Window Title Hotkey Options
menu Font Transparent #true
;menu Window transparent 75
menu Font Transparent #false
menu Show *rearmerMenuX *rearmerMenuY
menu Window Color $E7E7E7
menu Font BGColor $E7E7E7
menu Font Size 7
menu Text RAE 5 80 † Used to fix the issue where your ability
menu Text RAE2 12 92 flashes on/off, or doesn't activate.
menu Text RAE3 5 110 ‡ Shows current bindings.
menu Font Style bu
menu Font Size 8
menu Font Color black
menu Font BGColor $F9F9F9
menu Font Style
menu Button Prim 5 0 80 25 Primary
menu Button Sec 5 25 80 25 Secondary
menu Button MS 5 50 80 25 MS
menu Button Pause 90 0 80 25 Pause Casting
menu Button Play 90 25 80 25 Play Casting
menu Button Reset 90 50 80 25 Soft Reset †
menu Button Show 175 0 80 25 Show Menu
menu Button Hide 175 25 80 25 Hide Menu
menu Button Keymap 175 50 80 25 Keymap ‡
menu Button M3? 145 125 25 25 ?
menu Button M3Save 170 125 80 25 Save Hotkeys
return
sub menu4 ; Hotkey Selection Menu
menu window size 250 120
menu Window Title Key Binding
menu Font Transparent #true
menu Font Size 7
menu Font Align Left
menu Show *rearmerMenuX *rearmerMenuY
menu Window Color $E7E7E7
menu Font BGColor $E7E7E7
menu Font Style bu
menu text ABC 90 88 Key Modifier
menu text ABC2 135 1 Current %1 binding:
;menu text ABC3 158 40 Binding
menu Font Style i
menu text ABC4 140 15 Modifier
menu text ABC5 200 15 Key
menu Font Style
menu Font Color black
menu Font BGColor $F9F9F9
menu Font Size 8
set %temp %1 , Mod
if * . %temp = N/A
set * . %temp
if * . %1 = N/a
set * . %1
menu text CBMod 140 30 * . %temp
menu text CB 200 30 * . %1
menu Button F1 0 0 32 20 F1
menu Button F2 0 20 32 20 F2
menu Button F3 0 40 32 20 F3
menu Button F4 0 60 32 20 F4
menu Button F5 0 80 32 20 F5
menu Button F6 0 100 32 20 F6
menu Button F7 35 0 32 20 F7
menu Button F8 35 20 32 20 F8
menu Button F9 35 40 32 20 F9
menu Button F10 35 60 32 20 F10
menu Button F11 35 80 32 20 F11
menu Button F12 35 100 32 20 F12
menu Button Home 70 0 32 20 Home
menu Button End 70 20 32 20 End
menu Button Insert 70 40 32 20 Ins
menu Button Delete 70 60 32 20 Del
menu Button Ctrl 75 100 30 20 Ctrl
menu Button Alt 105 100 30 20 Alt
menu Button Shift 135 100 30 20 Shift
menu Button Clear 145 48 75 25 Clear Bindings
menu Button M4? 175 90 25 30 ?
menu Button M4Save 200 90 50 30 Save
return
sub menu5
menu window size 250 200
menu Window Title Hotkeys
menu Font Transparent #true
menu Font Size 8
menu Font Align Left
menu Show *rearmerMenuX *rearmerMenuY
menu Window Color $E7E7E7
menu Font BGColor $E7E7E7
menu Button M5Save 200 175 50 25 Return
menu Font Style u
menu text ABC1 5 1 Primary Hotkey:
menu text ABC2 5 60 Secondary Hotkey:
menu text ABC3 5 120 MS Hotkey:
menu text ABC4 155 1 Pause Hotkey:
menu text ABC5 155 60 Play Hotkey:
menu text ABC6 155 120 Reset Hotkey:
;menu text ABC3 158 40 Binding
menu Font Style i
menu Font Size 7
menu text MM1 5 17 Modifier
menu text MM2 5 77 Modifier
menu text MM3 5 137 Modifier
menu text MM4 155 17 Modifier
menu text MM5 155 77 Modifier
menu text MM6 155 137 Modifier
menu text KK1 50 17 Key
menu text KK2 50 77 Key
menu text KK3 50 137 Key
menu text KK4 200 17 Key
menu text KK5 200 77 Key
menu text KK6 200 137 Key
menu Font Style
menu Font Color black
menu Font Size 8
menu Font Style b
menu text CBM1 5 30 *PrimMod
menu text CBM2 5 90 *SecMod
menu text CBM3 5 150 *MSMod
menu text CBM4 155 30 *PauseMod
menu text CBM5 155 90 *PlayMod
menu text CBM6 155 150 *ResetMod
menu text CB1 50 30 *Prim
menu text CB2 50 90 *Sec
menu text CB3 50 150 *MS
menu text CB4 200 30 *Pause
menu text CB5 200 90 *Play
menu text CB6 200 150 *Reset
; menu Button M5? 175 175 25 25 ?
return
